Dreams:report-index

Rapporter

PREFIX target: <https://dreams.wikibase.cloud/entity/Q158>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT 
  ?udgivelsesdato 
  ?titel ?titelUrl
  ?miljøportal ?miljøportalUrl
WHERE {
  ?report dreamst:P2 / dreamst:P10* dreams:Q8 .
  OPTIONAL {
    ?report dreamst:P1 ?titel .
    BIND(CONCAT("#report/", SUBSTR(STR(?report), 38)) AS ?titelUrl)
  }
  OPTIONAL {
    ?report dreamsp:P6 / dreamspsv:P6 ?udgivelsesdato_value .
    ?udgivelsesdato_value wikibase:timePrecision ?time_precision ;
                            wikibase:timeValue ?udgivelsesdato_ .
    BIND(IF(?time_precision = 9, YEAR(?udgivelsesdato_), xsd:date(?udgivelsesdato_)) AS ?udgivelsesdato)
  }
  OPTIONAL {
    ?report dreamst:P40 ?miljøportal .
    BIND(IRI(CONCAT("https://daieproddreamspdfsto.blob.core.windows.net/files/", ?miljøportal)) AS ?miljøportalUrl)
  }
}
ORDER BY DESC(?udgivelsesdato)