Dreams:report

From DREAMS
Jump to navigation Jump to search

Rapportdata

PREFIX target: <https://dreams.wikibase.cloud/entity/Q158>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/værdi/> 

SELECT DISTINCT ?beskrivelse
  ?værdi ?værdiLabel ?værdiUrl
WHERE {
  BIND(target: AS ?work)
  {
    BIND(1 AS ?order)
    BIND("Titel" AS ?beskrivelse)
    ?work dreamst:P1 ?værdi .
  }
  UNION
  {
    BIND(2 AS ?order)
    BIND("Forfatter" AS ?beskrivelse)
    target: dreamst:P24 ?iri .
    BIND(SUBSTR(STR(?iri), 38) AS ?q) 
    ?iri rdfs:label ?værdi . 
    FILTER (LANG(?værdi) = 'da')
    BIND(CONCAT("#author/", ?q) AS ?værdiUrl)
  }
  UNION
  {
    BIND(2.5 AS ?order)
    BIND("Sprog" AS ?beskrivelse)
    ?work dreamst:P11 ?iri .
    ?iri rdfs:label ?værdi_string .
    FILTER (LANG(?værdi_string) = 'da')
    BIND(STR(?værdi_string) AS ?værdi)
  }
  UNION
  {
    BIND(6 AS ?order)
    BIND("Udgivelsesdato" AS ?beskrivelse)
    ?work dreamsp:P6 / dreamspsv:P6 ?publication_date_værdi .
    ?publication_date_værdi wikibase:timePrecision ?time_precision ;
                            wikibase:timeValue ?publication_date .
    BIND(IF(?time_precision = 9, YEAR(?publication_date), xsd:date(?publication_date)) AS ?værdi)
  }
  UNION
  {
    BIND(7 AS ?order)
    BIND("Udgiver" AS ?beskrivelse)
    ?work dreamst:P26 ?iri .
    BIND(SUBSTR(STR(?iri), 38) AS ?q) 
    ?iri rdfs:label ?værdi_string . 
    FILTER (LANG(?værdi_string) = 'da')
    BIND(COALESCE(?værdi_string, ?q) AS ?værdi)
    BIND(CONCAT("#publisher/", ?q) AS ?værdiUrl)
  }
  UNION
  {
    BIND(10 AS ?order)
    BIND("Projekttype" AS ?beskrivelse)
    ?work dreamst:P16 ?værdi .
    BIND(CONCAT("#projecttype/", SUBSTR(STR(?værdi), 38)) AS ?værdiUrl)
  }
  UNION
  {
    BIND(21 AS ?order)
    BIND("Scholia" AS ?beskrivelse)
    ?work dreamst:P3 ?værdi_ .
    BIND(CONCAT(STR(?værdi_), " ↗") AS ?værdi)
    BIND(CONCAT("https://scholia.toolforge.org/work/", STR(?værdi_)) AS ?værdiUrl)
  }
  UNION
  {
    BIND(22 AS ?order)
    BIND("Miljøportal" AS ?beskrivelse)
    ?work dreamst:P40 ?værdi_ .
    BIND(CONCAT(STR(?værdi_), " ↗") AS ?værdi)
    BIND(CONCAT("https://daieproddreamspdfsto.blob.core.windows.net/files/", STR(?værdi_)) AS ?værdiUrl)
  }
  UNION
  {
    BIND(100 AS ?order)
    BIND("Andre rapporter" AS ?beskrivelse)
    BIND("🔍" AS ?værdi)
    BIND(CONCAT("#report/", SUBSTR(STR(target:), 38), "/report") AS ?værdiUrl)
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],da,en". }
} 
ORDER BY ?order


Mønstre

PREFIX target: <https://dreams.wikibase.cloud/entity/Q406>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT
  ?mønster ("🔍" AS ?mønsterLabel)
  (CONCAT("#pattern/", SUBSTR(STR(?mønster), 38)) AS ?mønsterUrl)  

  ?subjekt ?subjektLabel ?subjektUrl

  ?påvirkning ?påvirkningLabel ?påvirkningUrl

  ?recipient ?recipientLabel ?recipientUrl

  ?signifikans ?signifikansLabel

  ?afbødning ?afbødningLabel ?afbødningUrl

  ?citat 

  ?projektfase ?projektfaseLabel
  (CONCAT("#projectphase/", SUBSTR(STR(?projektfase), 38)) AS ?projektfaseUrl)  

  ?projekttype ?projekttypeLabel
  (CONCAT("#projecttype/", SUBSTR(STR(?projekttype), 38)) AS ?projekttypeUrl)  

  ?link ?linkUrl

WITH {
  SELECT DISTINCT 
    ?mønster
    ?subjekt ?subjektLabel ?subjektUrl
    ?påvirkning ?påvirkningLabel ?påvirkningUrl
    ?recipient ?recipientLabel ?recipientUrl
    ?signifikans ?signifikansLabel
    ?afbødning ?afbødningLabel ?afbødningUrl
    ?citat
    ?projektfase
    ?projekttype
    ?link ?linkUrl
  WHERE {
    ?mønster dreamst:P2 dreams:Q263 ;
             dreamst:P20 target: .

    OPTIONAL {
      ?mønster dreamst:P33 ?subjekt .
      ?subjekt rdfs:label ?subjekt_label .
      FILTER(LANG(?subjekt_label) = 'da')
      BIND(CONCAT("#effect/", SUBSTR(STR(?subjekt), 38)) AS ?subjektUrl)
    }
    OPTIONAL { ?mønster dreamst:P47 ?subjekt_text }
    BIND(COALESCE(?subjekt, ?subjekt_text, "") AS ?subjekt)
    BIND(CONCAT(?subjekt_text, " (", COALESCE(?subjekt_label, ""), ")") AS ?subjektLabel)
    
    OPTIONAL {
      ?mønster dreamst:P34 ?påvirkning . 
      ?påvirkning rdfs:label ?påvirkning_label .
      FILTER (LANG(?påvirkning_label) = 'da')
      BIND(CONCAT("#effect/", SUBSTR(STR(?påvirkning), 38)) AS ?påvirkningUrl)
    }
    OPTIONAL { ?mønster dreamst:P49 ?påvirkning_text }
    BIND(COALESCE(?påvirkning, ?påvirkning_text) AS ?påvirkning)
    BIND(CONCAT(?påvirkning_text, " (", COALESCE(?påvirkning_label, ""), ")") AS ?påvirkningLabel)

    OPTIONAL {
      ?mønster dreamst:P55 ?recipient .
      ?recipient rdfs:label ?recipient_label .
      FILTER (LANG(?recipient_label) = 'da')
      BIND(CONCAT("#effect/", SUBSTR(STR(?recipient), 38)) AS ?recipientUrl)
    }
    OPTIONAL { ?mønster dreamst:P54 ?recipient_text }
    BIND(COALESCE(?recipient, ?recipient_text) AS ?recipient)
    BIND(CONCAT(?recipient_text, " (", COALESCE(?recipient_label, ""), ")") AS ?recipientLabel)
  
    OPTIONAL {
      ?mønster dreamst:P56 ?afbødning .
      ?afbødning rdfs:label ?afbødning_label .
      FILTER (LANG(?afbødning_label) = 'da')
      BIND(CONCAT("#effect/", SUBSTR(STR(?afbødning), 38)) AS ?afbødningUrl)
    }
    OPTIONAL { ?mønster dreamst:P53 ?afbødning_text }
    BIND(COALESCE(?afbødning, ?afbødning_text) AS ?afbødning)
    BIND(CONCAT(?afbødning_text, " (", COALESCE(?afbødning_label, ""), ")") AS ?afbødningLabel)

    OPTIONAL { ?mønster dreamst:P18 ?citat . }
   
    OPTIONAL { ?mønster dreamst:P19 ?projektfase . }
    
    OPTIONAL { ?mønster dreamst:P16 ?projekttype1 . }
    OPTIONAL { ?mønster dreamst:P20 / dreamst:P16 ?projekttype2 . }
    BIND(COALESCE(?projekttype1, ?projekttype2) AS ?projekttype)
                 
    OPTIONAL {
      ?mønster dreamst:P21 ?signifikans .
      ?signifikans rdfs:label ?signifikans_text .
      FILTER (LANG(?signifikans_text) = 'da')
      OPTIONAL { ?signifikans dreamst:P44 ?symbol . }
      BIND(IF(BOUND(?symbol), ?symbol, "❓") AS ?signifikans_symbol)
      BIND(CONCAT(?signifikans_symbol, " ", ?signifikans_text) AS ?signifikansLabel)
    }

    OPTIONAL {
      ?mønster dreamst:P20 ?report .
      ?report dreamst:P40 ?miljøportal .
      OPTIONAL { ?mønster dreamst:P46 ?page }
      BIND(IF(BOUND(?page), CONCAT(?page, " ↗"), " ↗") AS ?link)
      BIND(CONCAT("https://daieproddreamspdfsto.blob.core.windows.net/files/", STR(?miljøportal), 
                  IF(BOUND(?page), CONCAT("#page=", ?page), "")) AS ?linkUrl)
    }
  }
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}


Steder

PREFIX target: <https://dreams.wikibase.cloud/entity/Q158>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspr: <https://dreams.wikibase.cloud/prop/reference/>
PREFIX dreamsps: <https://dreams.wikibase.cloud/prop/statement/> 
PREFIX prov: <http://www.w3.org/ns/prov#>

SELECT 
  ?sted ?stedLabel
  (CONCAT("#location/", SUBSTR(STR(?sted), 38)) AS ?stedUrl)
  ?stedDescription

  ?citat
WHERE {
  target: dreamsp:P12 ?sted_statement .
  ?sted_statement dreamsps:P12 ?sted .
  OPTIONAL {
    ?sted_statement prov:wasDerivedFrom / dreamspr:P18 ?citat .
  }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}


Citations SPARQL | query= PREFIX target: <https://dreams.wikibase.cloud/entity/Q100> PREFIX dreams: <https://dreams.wikibase.cloud/entity/> PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/> PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/> PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/>

SELECT 

 ?title

 ("Scholia ↗" AS ?scholia) 
 ?scholiaUrl

WHERE { 

 target: dreamst:P3 ?wikidata_q .
 BIND(IRI(CONCAT("http://www.wikidata.org/entity/", ?wikidata_q)) AS ?wikidata)
 
 SERVICE <https://query.wikidata.org/sparql> {
   ?wikidata wdt:P2860 ?cited .
   OPTIONAL {
     ?cited wdt:P1476 ?title .
   }
   BIND(CONCAT("https://scholia.toolforge.org/work/", SUBSTR(STR(?cited), 32)) AS ?scholiaUrl)
 }

} }} 

Related works from co-citations

SPARQL | query= PREFIX target: <https://dreams.wikibase.cloud/entity/Q100> PREFIX dreams: <https://dreams.wikibase.cloud/entity/> PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>

SELECT 

 ?score
 ?title ?titleUrl
 ("Scholia ↗" AS ?scholia) ?scholiaUrl

WHERE { 

 { 
   SELECT 
     (COUNT(*) AS ?score)
     ?work ?title
   WHERE {
     target: dreamst:P3 ?wikidata_q .
     BIND(IRI(CONCAT("http://www.wikidata.org/entity/", ?wikidata_q)) AS ?wikidata)
 
     SERVICE <https://query.wikidata.org/sparql> {
       ?wikidata (^wdt:P2860 | wdt:P2860) / (^wdt:P2860 | wdt:P2860)? ?work .
       FILTER (?wikidata != ?work)
       ?work wdt:P1476 ?title .
     }
   }
   GROUP BY ?work ?title 
   ORDER BY DESC(?count)
   LIMIT 500
 }
 BIND(CONCAT("https://scholia.toolforge.org/work/", SUBSTR(STR(?work), 32)) AS ?scholiaUrl)
 BIND(SUBSTR(STR(?work), 32) AS ?work_q)
 OPTIONAL {
   ?dreams_work dreamst:P3 ?work_q .
   BIND(CONCAT("#report/", SUBSTR(STR(?dreams_work), 38)) AS ?titleUrl)
 }

} ORDER BY DESC(?score) DESC(?titleUrl)

}}

Retrieved from "https://dreams.wikibase.cloud/w/index.php?title=Dreams:report&oldid=17590"