Dreams:report-index

PREFIX target: <https://dreams.wikibase.cloud/entity/Q158>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT 
  ?publication_date 
  ?title ?titleUrl
  ?miljøportal ?miljøportalUrl
WHERE {
  ?report dreamst:P2 / dreamst:P10* dreams:Q8 .
  OPTIONAL {
    ?report dreamst:P1 ?title .
    BIND(CONCAT("#report/", SUBSTR(STR(?report), 38)) AS ?titleUrl)
  }
  OPTIONAL {
    ?report dreamsp:P6 / dreamspsv:P6 ?publication_date_value .
    ?publication_date_value wikibase:timePrecision ?time_precision ;
                            wikibase:timeValue ?publication_date_ .
    BIND(IF(?time_precision = 9, YEAR(?publication_date_), xsd:date(?publication_date_)) AS ?publication_date)
  }
  OPTIONAL {
    ?report dreamst:P40 ?miljøportal .
    BIND(IRI(CONCAT("https://daieproddreamspdfsto.blob.core.windows.net/files/", ?miljøportal)) AS ?miljøportalUrl)
  }
}
ORDER BY DESC(?publication_date)