Dreams:pattern-index

Patterns

PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT
  ?pattern ?patternLabel
  (CONCAT("#pattern/", SUBSTR(STR(?pattern), 38)) AS ?patternUrl)

  ?subject ?subjectLabel
  (CONCAT("#effect/", SUBSTR(STR(?subject), 38)) AS ?subjectUrl)

  ?object ?objectLabel
  (CONCAT("#effect/", SUBSTR(STR(?object), 38)) AS ?objectUrl)

  ?recipient ?recipientLabel
  (CONCAT("#effect/", SUBSTR(STR(?recipient), 38)) AS ?recipientUrl)

  ?quote 
  ?project_phase ?project_phaseLabel
  ?project_type ?project_typeLabel

  ?report ?reportLabel
  (CONCAT("#report/", SUBSTR(STR(?report), 38)) AS ?reportUrl)

WHERE {
  ?pattern dreamst:P2 dreams:Q263 .

  OPTIONAL { ?pattern dreamst:P33 ?subject . }
  OPTIONAL { ?pattern dreamst:P34 ?object . }
  OPTIONAL { ?pattern dreamst:P54 ?recipient . }

  OPTIONAL { ?pattern dreamst:P18 ?quote . }
  OPTIONAL { ?pattern dreamst:P20 ?report . }
  OPTIONAL { ?pattern dreamst:P19 ?project_phase . }
  OPTIONAL { ?pattern dreamst:P16 ?project_type . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}

Reports

PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT 
  ?number_of_patterns

  ?report 
  ?reportLabel
  (CONCAT("#report/", SUBSTR(STR(?report), 38)) AS ?reportUrl)
          
WITH {
  SELECT
    (COUNT(?pattern) AS ?number_of_patterns)
    ?report
  WHERE {
    ?pattern dreamst:P2 dreams:Q263 ;
             dreamst:P20 ?report .
  }
  GROUP BY ?report
} AS %result
WHERE {
  INCLUDE %result
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY DESC(?number_of_patterns)