Dreams:location

Steddata

PREFIX target: <https://dreams.wikibase.cloud/entity/Q306>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT DISTINCT ?beskrivelse ?value ?valueLabel ?valueUrl
WHERE {
  {
    BIND(1 AS ?order)
    BIND("Sted" AS ?beskrivelse)
    BIND(target: AS ?value) .
  }
  UNION
  {
    BIND(10 AS ?order)
    BIND("OpenStreetMap" AS ?beskrivelse)
    target: dreamsp:P13 ?geo_statement .
    ?geo_statement dreamspsv:P13 / wikibase:geoLatitude ?latitude .
    ?geo_statement dreamspsv:P13 / wikibase:geoLongitude ?longitude .
    BIND(CONCAT(STR(?latitude), "/", STR(?longitude), " ↗") AS ?value)
    BIND(CONCAT("https://www.openstreetmap.org/#map=15/",
                STR(?latitude), "/", STR(?longitude)) AS ?valueUrl)
  }
  UNION
  {
    BIND(21 AS ?order)
    BIND("Scholia" AS ?beskrivelse)
    target: dreamst:P3 ?value_ .
    BIND(CONCAT(STR(?value_), " ↗") AS ?value)
    BIND(CONCAT("https://scholia.toolforge.org/topic/", STR(?value_)) AS ?valueUrl)
  }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY ?order

Rapporter

PREFIX target: <https://dreams.wikibase.cloud/entity/Q306>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>

SELECT 
  ?rapport ?rapportLabel
  (CONCAT("#report/", SUBSTR(STR(?rapport), 38)) AS ?rapportUrl)
WHERE {
  ?rapport dreamst:P12 target: .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],da,en". }
}

Samnævnte steder

PREFIX target: <https://dreams.wikibase.cloud/entity/Q306>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>

SELECT 
  (COUNT(?rapport) AS ?count)
  ?sted ?stedLabel
  (CONCAT("#location/", SUBSTR(STR(?sted), 38)) AS ?stedUrl) ?stedDescription
WHERE {
  ?rapport dreamst:P12 target: , ?sted .
  FILTER (target: != ?sted) 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],da,en". }
}
GROUP BY ?sted ?stedLabel ?stedUrl ?stedDescription

Nære steder

PREFIX target: <https://dreams.wikibase.cloud/entity/Q306>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT
  ?afstand 
  ?sted ?stedLabel ?stedUrl ?stedDescription
WHERE {
  target: dreamst:P13 ?geo .
  ?sted dreamst:P13 ?other_geo .
  FILTER(target: != ?sted)
  BIND(geof:distance(?other_geo, ?geo) AS ?afstand)
  BIND(CONCAT("#location/", SUBSTR(STR(?sted), 38)) AS ?stedUrl)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY ?afstand