Dreams:projecttype

Project type data

PREFIX target: <https://dreams.wikibase.cloud/entity/Q264>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>

SELECT DISTINCT ?description ?value ?valueLabel ?valueUrl
WHERE {
  BIND(target: AS ?effect)
  {
    BIND(1 AS ?order)
    BIND("Project type" AS ?description)
    BIND(target: AS ?value) .
  }
  UNION
  {
    BIND(5 AS ?order)
    BIND("Supertype" AS ?description)
    target: dreamst:P10 ?value .
    BIND(SUBSTR(STR(?value), 38) AS ?q) 
    BIND(CONCAT("#project-type/", ?q) AS ?valueUrl)
  }
  UNION
  {
    BIND(6 AS ?order)
    BIND("Subtype" AS ?description)
    target: ^dreamst:P10 ?value .
    BIND(SUBSTR(STR(?value), 38) AS ?q) 
    BIND(CONCAT("#project-type/", ?q) AS ?valueUrl)
  }
  UNION
  {
    BIND(10 AS ?order)
    BIND("External description" AS ?description)
    target: dreamst:P29 ?value .
    BIND(?value AS ?valueUrl)
  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}
ORDER BY ?order

Effects

PREFIX target: <https://dreams.wikibase.cloud/entity/Q264>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT
  ?number_of_patterns

  ?effect ?effectLabel
  (CONCAT("#effect/", SUBSTR(STR(?effect), 38)) AS ?effectUrl)  

  ?example_pattern ?example_patternLabel
  (CONCAT("#pattern/", SUBSTR(STR(?example_pattern), 38)) AS ?example_patternUrl)  
 
WITH {
  SELECT 
    (COUNT(?pattern) AS ?number_of_patterns)
    (SAMPLE(?pattern) AS ?example_pattern)
    ?effect
  WHERE {
    ?pattern dreamst:P2 dreams:Q263 ;
             dreamst:P16 / dreamst:P10* target: ;
             dreamst:P33

Reports

PREFIX target: <https://dreams.wikibase.cloud/entity/Q170>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>

SELECT 
  ?project_type ?project_typeLabel
  (CONCAT("#project-type/", SUBSTR(STR(?project_type), 38)) AS ?project_typeUrl)

  ?report ?reportLabel
  (CONCAT("#report/", SUBSTR(STR(?report), 38)) AS ?reportUrl)

WHERE {
  ?project_type dreamst:P10* target: .
  ?report dreamst:P2 / dreamst:P10* dreams:Q8 ;   
          dreamst:P16 ?project_type .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en,it". }
}

Patterns

PREFIX target: <https://dreams.wikibase.cloud/entity/Q702>
PREFIX dreams: <https://dreams.wikibase.cloud/entity/>
PREFIX dreamst: <https://dreams.wikibase.cloud/prop/direct/>
PREFIX dreamsp: <https://dreams.wikibase.cloud/prop/>
PREFIX dreamspsv: <https://dreams.wikibase.cloud/prop/statement/value/> 

SELECT
  ?pattern ?patternLabel
  (CONCAT("#pattern/", SUBSTR(STR(?pattern), 38)) AS ?patternUrl)  

  ?subject ?subjectLabel
  (CONCAT("#effect/", SUBSTR(STR(?subject), 38)) AS ?subjectUrl)  

  ?object ?objectLabel
  (CONCAT("#effect/", SUBSTR(STR(?object), 38)) AS ?objectUrl)  

  ?quote 

  ?project_phase ?project_phaseLabel
  (CONCAT("#project-phase/", SUBSTR(STR(?project_phase), 38)) AS ?project_phaseUrl)  

  ?report ?reportLabel
  (CONCAT("#report/", SUBSTR(STR(?report), 38)) AS ?reportUrl)  

WHERE {
  ?pattern dreamst:P2 dreams:Q263 ;
           dreamst:P16 / dreamst:P10* target: .

  OPTIONAL { ?pattern dreamst:P33 ?subject . }
  OPTIONAL { ?pattern dreamst:P34 ?object . }
  OPTIONAL { ?pattern dreamst:P18 ?quote . }
  OPTIONAL { ?pattern dreamst:P19 ?project_phase . }
  OPTIONAL { ?pattern dreamst:P20 ?report . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
}